New!! Arduinoで物体との距離を測る（①超音波距離センサー編）

//センサー数
const int NUM_SENSORS = 2;

//Trig, Echoピン
int trigPins[NUM_SENSORS] = {2, 4};
int echoPins[NUM_SENSORS] = {3, 5};

//ブザーピン
const int buzzerPin = 11;

//検出しきい値[cm]
const float THRESHOLD_CM = 10.0;

//検出タイムアウト[us], 5000us≒往復約85cm程度
const unsigned long TIMEOUT_US = 5000;

//距離配列[cm]
float distanceCm[NUM_SENSORS];

//検出配列
bool isNear[NUM_SENSORS];

void setup() {
  Serial.begin(9600);
  //センサー初期化
  for (int i = 0; i < NUM_SENSORS; i++) {
    pinMode(trigPins[i], OUTPUT);
    pinMode(echoPins[i], INPUT);
    digitalWrite(trigPins[i], LOW);
  }
  //ブザー初期化
  pinMode(buzzerPin, OUTPUT);
  digitalWrite(buzzerPin, LOW);
}

//1つのセンサーで距離を測る関数
float measureDistanceCm(int index) {
  int trig = trigPins[index];
  int echo = echoPins[index];
  
  //TrigをいったんLOW
  digitalWrite(trig, LOW);
  delayMicroseconds(2);
  
  //10usのパルスを発射
  digitalWrite(trig, HIGH);
  delayMicroseconds(10);
  digitalWrite(trig, LOW);

  //EchoがHIGHの間の時間を測る（タイムアウト付き）
  unsigned long duration = pulseIn(echo, HIGH, TIMEOUT_US);

  //エコーが返ってこなかったら-1.0を返す
  if (duration == 0) {
    return -1.0;
  }

  //返ってきたら距離[cm]
  float d = duration * 340 / 10000 / 2;
  return d;
}

void loop() {
  //全センサー
  for (int i = 0; i < NUM_SENSORS; i++) {
    //距離[cm]
    distanceCm[i] = measureDistanceCm(i);
    //検出結果
    if (distanceCm[i] > 0 && distanceCm[i] <= THRESHOLD_CM) {
      isNear[i] = true;
    } else {
      isNear[i] = false;
    }
    //クロストーク防止のために少し待つ[ms]
    delay(5);
  }

  //配列isNear[]の中にtrueが一つでもあるかチェック
  bool anyNear = false;
  for (int i = 0; i < NUM_SENSORS; i++) {
    if (isNear[i]) {
      anyNear = true;
      break;
    }
  }

  //あればブザーを鳴らす
  if (anyNear) {
    //パッシブブザーなのでtone()で交流を出す
    tone(buzzerPin, 442);       //4kHz
  } else {
    noTone(buzzerPin);           // ブザー OFF
  }

  //ループ待機[ms]
  delay(50);
}

d = duration * 340 / 10000 / 2;

tone(buzzerPin, 442);