New!! Arduinoで物体との距離を測る（③車のバックセンサー編）

//バックソナーからの入力ピン
const int sonarPin  = 2;

//Arduinoのブザーピン
const int buzzerPin = 11;

const int WINDOW_SAMPLES = 20;   //1秒のウインドウ (50ms × 20回)
bool windowBuf[WINDOW_SAMPLES];
int indexPos = 0;
int highCount = 0;

void setup() {
  Serial.begin(9600);
  //センサー初期化
  pinMode(sonarPin, INPUT);
  //ブザー初期化
  pinMode(buzzerPin, OUTPUT);
  digitalWrite(buzzerPin, LOW);
  //バッファ初期化（すべてLOWとして扱う）
  for (int i = 0; i < WINDOW_SAMPLES; i++) {
    windowBuf[i] = false;
  }
}

void loop() {
  //バックソナーの信号読み取り
  bool sonarHigh = digitalRead(sonarPin);

  //Arduinoのブザーを鳴らす
  if (sonarHigh) {
    tone(buzzerPin, 442);       //4kHz
  } else {
    noTone(buzzerPin);          // ブザー OFF
  }

  //移動ウインドウに現在の値を入れると同時に古い値を引く
  if (sonarHigh && !windowBuf[indexPos]) {
    highCount++;          // LOW→HIGH に変わった
  } else if (!sonarHigh && windowBuf[indexPos]) {
    highCount--;          // HIGH→LOW に変わった
  }
  windowBuf[indexPos] = sonarHigh;
  indexPos = (indexPos + 1) % WINDOW_SAMPLES;

  //HIGH率
  float highRatio = (float)highCount / (float)WINDOW_SAMPLES;

  Serial.print("High ratio: ");
  Serial.print(highRatio, 2);
  Serial.print(" -> ");

  //判定
  if (highRatio <= 0.10) {
    Serial.println("Level 0");
  } else if (highRatio <= 0.35) {
    Serial.println("Level 1");
  } else if (highRatio <= 0.80) {
    Serial.println("Level 2");
  } else {
    Serial.println("Level 3");
  }

  //ループ待機[ms]
  delay(50);
}