New!! Arduinoで物体との距離を測る（②レーザー測距センサー編）

#include <Wire.h>
#include <VL53L0X.h>

//ブザーピン
const int buzzerPin = 11;

//検出しきい値[cm]
const float THRESHOLD_CM = 10.0;

//VL53L0Xオブジェクト
VL53L0X sensor;

void setup() {
  Serial.begin(9600);
  Wire.begin();
  Wire.setClock(100000);

  //センサー初期化
  sensor.init();
  //タイムアウト[ms]
  sensor.setTimeout(10);

  //ブザー初期化
  pinMode(buzzerPin, OUTPUT);
  digitalWrite(buzzerPin, LOW);
}

//センサーで距離[cm]を測る関数
float measureDistanceCm() {
  //計測[mm]
  uint16_t distanceMm = sensor.readRangeSingleMillimeters();

  //タイムアウト、0や非常に大きい値は-1.0を返す
  if (sensor.timeoutOccurred() || distanceMm == 0 || distanceMm > 4000) {
    return -1.0;
  }

  //変換[mm]→[cm]
  float d = distanceMm / 10.0;
  return d;
}

void loop() {
  //距離[cm]
  float distanceCm = measureDistanceCm();

  //検出結果
  bool isNear = (distanceCm > 0 && distanceCm <= THRESHOLD_CM);

  //検出されればブザーを鳴らす
  if (isNear) {
    tone(buzzerPin, 442);       //4kHz
  } else {
    noTone(buzzerPin);          // ブザー OFF
  }

  //ループ待機[ms]
  delay(50);
}